2 formas de fusionar rápidamente varios documentos de Word en uno a través de VBA

En este artículo, nos complace compartir con usted 2 formas de fusionar rápidamente varios documentos de Word en uno a través de VBA.

En Word, existe la función incorporada predeterminada para ayudar al usuario a combinar o fusionar varios documentos en uno. Los detalles se explican en este artículo: Cómo combinar y fusionar varios documentos de Word en uno

Con ese método tienes que hacer un par de clics y el contenido del siguiente documento siempre viene inmediatamente después del anterior. Por lo tanto, queremos ofrecerle formas más rápidas de hacerlo.

Método 1: fusionar documentos seleccionados en uno

1. Primero y primeroost, cree un nuevo documento en blanco.
2. Active el editor de VBA en Word presionando “Alt + F11”.
3. A continuación, haga clic en "Normal".
4. Luego haga clic en "Insertar".
5. Y elija "Módulo".
6. Haga doble clic en el nuevo módulo para abrir el espacio de edición.
7. Pegue la siguiente macro allí:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Luego haga clic en “Ejecutar” o presione “F5”.
9. Ahora, en la ventana "Examinar", seleccione varios archivos presionando "Ctrl" y haga clic en "Aceptar".
10. Luego, todo el contenido de los archivos seleccionados se juntará en el nuevo documento, con los textos de cada documento.tarting en una nueva página.

Nota:

Como mencionamos, esta macro coloca los textos de cada documento en una nueva página. Pero si necesita que sean uno tras otro, puede modificar algunas líneas de código en la macro. Simplemente busque la línea “If nEachSelectedFile <nTotalFiles Then”, bórrelo y las siguientes seis líneas también.

Método 2: fusionar todos los documentos de una carpeta en uno

En caso de que tenga una carpeta de archivos para combinar, esta macro funcionará a la perfección.

1. A start apagado, instale y ejecute la macro como se describe en el método 1.
2. Luego reemplace la macro con esta:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Ejecute la macro haciendo clic en "Ejecutar".
4. A continuación, verá abierta la ventana "Examinar". Seleccione la carpeta donde almacena todos los documentos. Y haga clic en "Aceptar".

Asimismo, los textos de cada documento starts en una página nueva. Para que se peguen uno tras otro, busque y elimine la línea de código ".InsertBreak Type: = wdPageBreak".

Proteja su documento de Word correctamente

Una de las mejores formas de proteger sus documentos de Word es hacer copias de seguridad de ellos con regularidad. Con las copias de seguridad en la mano, nunca tendrá que temer la pérdida de datos. Además, también es recomendable tener una herramienta para reparar docx si alguno de ellos se daña.

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo Excel dañado y pdf reparar productos de software. Para más información visite www.datanumen.com