如何快速將每個Outlook文件夾中的項目總數導出到Excel

Outlook解決方案 2025 年 9 月 29 日

如果要獲取有關每個Outlook文件夾中項目計數的報告，則可以使用本文介紹的方法。它將快速進行計數並將結果導出到Excel文件中。

在我上一篇文章中-“如何通過Outlook VBA快速獲取文件夾及其所有子文件夾中的項目總數”，您可以學習使用VBA來獲取文件夾中項目數的方法。但是，通過這種方式，如果要計算所有文件夾中的項目，則必須選擇每個文件夾並逐個運行宏。這有點乏味。因此，我們將教給您另一種方法，該方法會將計數導出到Excel文件。

將每個Outlook文件夾中的項目總數導出到Excel

首先，啟動Outlook程序。
然後在Outlook主窗口中按“ Alt + F11”鍵按鈕。
接下來，您將進入“ Microsoft Visual Basic for Applications”窗口，在其中您需要打開一個未使用的模塊。
隨後，將以下VBA代碼複製並粘貼到該模塊中。

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

之後，您需要將Outlook宏安全級別更改為低。
然後，您可以返回到新添加的宏，然後按F5鍵按鈕運行該宏。
接下來，您需要選擇一個源PST文件，然後單擊“確定”。
宏完成後，您可以轉到預定義的本地文件夾以找到新的Excel文件，該文件類似於以下屏幕截圖：

解決煩人的PST錯誤

也許您在使用Outlook時遇到了各種問題。要解決小問題，您可以簡單地訴諸收件箱維修工具。但是，如果問題非常嚴重，以至於超出了內置工具無法解決的範圍，則必須使用功能更強大的工具，例如 DataNumen Outlook Repair.

作者簡介：

Shirley Zhang是的數據恢復專家 DataNumen，Inc.是數據恢復技術的全球領導者，包括 mdf維修和Outlook修復軟件產品。欲了解更多信息，請訪問萬維網。datanumen.COM