Como exportar rapidamente todas as pastas e itens do Outlook na seção “Favoritos” para uma pasta do Windows

Se você deseja exportar todas as pastas do Outlook, bem como seus itens na seção “Favoritos”, consulte este artigo. Aqui vamos mostrar-lhe como realizá-lo em tempo rápido.

Geralmente, as pastas e seus itens na seção “Favoritos” são de grande importância e frequentemente necessários. Portanto, às vezes, você pode querer exportá-los para a unidade local. Da maneira padrão, você deve criar pastas do Windows de acordo com as pastas em “Favoritos” e salvar itens como arquivos MSG um a um na unidade local. Isso é muito tedioso. Portanto, aqui vamos expor uma maneira muito mais eficiente. Agora continue a ler para obtê-lo.

Exportar todas as pastas e itens na seção “Favoritos” para uma pasta do Windows

1. Para começar, acesse o editor VBA no Outlook consultando “Como executar o código VBA no seu Outlook".
2. Em seguida, copie o código a seguir em um módulo vazio.

Sub ExportAllFoldersItems_InFavorites_ToWindowsFolder()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim objFileSystem As Object
    Dim strWindowsFolder As String
    Dim objNavigationPane As Outlook.NavigationPane
    Dim objNavigationModule As Outlook.NavigationModule
    Dim objNavigationGroup As Outlook.NavigationGroup
    Dim objNavigationFolder As Outlook.NavigationFolder
    Dim objFolder As Outlook.Folder
    Dim strFolderPath As String
    Dim objItem As Object
    Dim strFilePath As String
    Dim i As Long
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
     
       'Get "Favorites" section
       Set objNavigationPane = Application.ActiveExplorer.NavigationPane
       Set objNavigationModule = objNavigationPane.Modules.GetNavigationModule(olModuleMail)
       Set objNavigationGroup = objNavigationModule.NavigationGroups.GetDefaultNavigationGroup(olFavoriteFoldersGroup)
 
       'Export the folders and items in "Favorites" section
       For Each objNavigationFolder In objNavigationGroup.NavigationFolders
           Set objFolder = objNavigationFolder.Folder
           strFolderPath = strWindowsFolder & objFolder.Name
           objFileSystem.CreateFolder strFolderPath
 
           For Each objItem In objFolder.Items
               strSubject = objItem.Subject
               strFileName = strSubject & ".msg"
 
               i = 0
               Do Until False
                  strFilePath = strFolderPath & "\" & strFileName
                  If objFileSystem.FileExists(strFilePath) Then
                     i = i + 1
                     strFileName = strSubject & " (" & i & ").msg"
                  Else
                     Exit Do
                  End If
               Loop
 
               objItem.SaveAs strFilePath, olMSG
          Next
       Next
 
       'Open the Windows folder
       Call Shell("explorer.exe " & strWindowsFolder, vbNormalFocus)
    End If
End Sub

3. Em seguida, clique no ícone "Executar" na barra de ferramentas.
4. Em seguida, na caixa de diálogo pop-up, selecione uma pasta de destino do Windows e clique em “OK”.
5. Quando a macro terminar, a pasta do Windows será exibida.
6. Nesta pasta do Windows, as pastas e seus itens na seção “Favoritos” foram exportados, conforme a captura de tela a seguir.

Restaurar dados do Outlook de backups

É altamente recomendável fazer backup dos arquivos do Outlook regularmente. É porque se você sofre corrupção de arquivo do Outlook, você pode recuperar Outlook dados de backups facilmente. Mas, se você não tiver esse backup, precisará tentar uma árdua correção do Outlook. Nesse momento, a ferramenta de reparo da caixa de entrada não será de muita ajuda. Você tem que ter ajuda de ferramenta externa fixa, como DataNumen Outlook Repair.

Introdução do autor:

Shirley Zhang é especialista em recuperação de dados em DataNumen, Inc., líder mundial em tecnologias de recuperação de dados, incluindo sql corrompido e produtos de software de reparo do Outlook. Para mais informações visite www.datanumen.com