Kaip greitai pritvirtinti konkrečias skaidres a PowerPoint Pristatymas jūsų Outlook el

Jei norite išgauti konkrečias skaidres a PowerPoint pristatymą į atskirą naują pristatymą ir pridėkite jį prie „Outlook“ el. laiško, galite pasinaudoti šiame straipsnyje aprašytu būdu.

Užuot prijungę visą PowerPoint pristatymą į el. laišką, jei norite pridėti konkrečias pristatymo skaidres, apskritai pirmiausia turite nukopijuoti konkrečias skaidres į naują pristatymą. Tai per daug varginanti. Todėl čia parodysime metodą, kuris gali jį įgyvendinti vienu ypu.

Pritvirtinkite konkrečias skaidres a PowerPoint Pristatymas el

1. Pirmiausia atidarykite konkretų PowerPoint pristatymas.
2. Tada PowerPoint programos lange paspauskite „Alt + F11“, kad pasiektumėte VBA redaktorių.
3. Tada naujame lange sukurkite naują modulį paspausdami „Įterpti“ > „Modulis“.
4. Tada nukopijuokite ir įklijuokite šį VBA kodą į šį modulį.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Po to galite uždaryti dabartinį langą.
6. Vėliau eikite į „Failas“ > „Parinktys“ > „Greitos prieigos įrankių juosta“, kad pridėtumėte naują makrokomandą prie greitosios prieigos įrankių juostos.
7. Galiausiai galite išbandyti šią makrokomandą.

• Dėl astart, pasirinkite konkrečias skaidres, kurias norite išgauti.
• Tada greitosios prieigos įrankių juostoje spustelėkite makrokomandos mygtuką.
• Iš karto pasirodys „Outlook“ el. laiškas, kuriame yra a PowerPoint pristatymas, kuris yra ištrauktas iš šaltinio pristatymo.

Naudokite veiksmingą atkūrimo įrankį

Kaip visi žinome, „Outlook“ yra aprūpinta integruota taisymo programa – scanpst. Tačiau jis gali tiesiog susidoroti su mažais „Outlook“ trūkumais. Jei tai, su kuo susidūrėte, yra rimta žala, tai neduos pasekmių. Tuo metu jūs neturite kito pasirinkimo, kaip naudoti kitą galingą ir patikimą remonto įrankį, pvz., DataNumen Outlook Repair. Su juo galėsite išgelbėti sugadintą „Outlook“ failą.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant sugadintas mdf ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com