Cómo eliminar automáticamente las direcciones de correo electrónico del remitente y los destinatarios originales al reenviar un correo electrónico de Outlook

Cuando reenvía un correo electrónico en Outlook, las direcciones de correo electrónico del remitente y los destinatarios originales se incluirán en el cuerpo del mensaje. En este momento, por seguridad, es mejor que elimine estas direcciones. Esta post le enseñará a dejar que Outlook lo haga automáticamente.

En muchos casos, deberá reenviar algunos correos electrónicos a otra persona. De forma predeterminada, el encabezado del correo electrónico original se mostrará en el cuerpo del correo electrónico de reenvío. Y el encabezado incluirá las direcciones de correo electrónico del remitente y los destinatarios originales. En este punto, por seguridad o privacidad, es posible que desee eliminar estas direcciones de correo electrónico. Sin embargo, es demasiado tedioso eliminarlos manualmente. Por lo tanto, aquí lo guiaremos para que Outlook realice esta tarea automáticamente en su nombre.

Eliminación automática de las direcciones de correo electrónico del remitente y los destinatarios originales al reenviar un correo electrónico

1. Porque comotart, inicie Outlook.
2. Luego, presione los botones de tecla "Alt + F11" para acceder al editor de VBA.
3. A continuación, copie el siguiente código VBA en el proyecto "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objRegExp As Object
    Dim strHTMLBody As String
 
    Forward.Display
    strHTMLBody = Forward.HTMLBody
 
    'Find email addresses in the body via Regular Expression
    Set objRegExp = CreateObject("vbscript.RegExp")
    With objRegExp
        .Pattern = "(?:[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*|""(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21\x23-\x5b\x5d-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])*"")@(?:(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?|\[(?:(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.){3}(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?|[a-z0-9-]*[a-z0-9]:(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21-\x5a\x53-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])+)\])"
        .IgnoreCase = True
        .Global = True
    End With
 
    'Remove email addresses
    If objRegExp.Test(strHTMLBody) Then
       Set objFoundResults = objRegExp.Execute(strHTMLBody)
       For i = 1 To objFoundResults.Count
           Forward.HTMLBody = Replace(Forward.HTMLBody, objFoundResults.Item(i - 1).Value, "")
       Next
    End If
 
    'Remove useless characters
    Forward.HTMLBody = Replace(Forward.HTMLBody, "[mailto:]", "")
    Forward.HTMLBody = Replace(Forward.HTMLBody, "()", "")
End Sub

4. Después de eso, restart su programa Outlook para activar esta nueva macro.
5. Eventualmente, puedes tomar una foto:

• Seleccione o abra un correo electrónico.
• Luego, haga clic en el botón "Reenviar" en el grupo "Responder".
• Por último, se mostrará un nuevo correo electrónico de reenvío, en el que se han eliminado las direcciones de correo electrónico del remitente y los destinatarios originales.

Cálmate en caso de corrupción de Outlook

Cuando está sujeto a algún problema en su Outlook, puede entrar en pánico, tener miedo de Corrupción de Outlook. Sin embargo, para ser honesto, la prisa y la preocupación pueden generar muchos otros problemas en Outlook. Por lo tanto, no entre en pánico pero mantenga la calma en los casos relevantes. Además, si ha mantenido una sólida herramienta de reparación de PST, como DataNumen Outlook Repair, simplemente puede emplearlo para resolver problemas de Outlook.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo arreglar sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com