So suchen und ersetzen Sie Text in mehreren Outlook-E-Mails im Stapel

Standardmäßig unterstützt Outlook Sie nicht, Text in mehreren E-Mails gleichzeitig zu suchen und zu ersetzen. Wenn Sie dies tun möchten, können Sie sich daher auf diesen Artikel beziehen. Hier zeigen wir Ihnen, wie Sie dies per VBA-Code realisieren können.

Sie haben beispielsweise mehrere E-Mails in Outlook fertig gestellt. Bevor Sie sie versenden, entdecken Sie einige Fehler und möchten einige Texte in diesen E-Mails ändern. Im Allgemeinen müssen Sie in jeder E-Mail nacheinander „Suchen und Ersetzen“ ausführen. Trotzdem ist es zu umständlich. Daher zeigen wir Ihnen hier einen effektiveren Weg, mit dem Sie dies in großen Mengen erreichen können.

Batch-Suchen und Ersetzen von Text in mehreren E-Mails

1. Zunächst start Ihr Outlook-Programm.
2. Greifen Sie dann über die Tasten "Alt + F11" auf den VBA-Editor zu.
3. Fügen Sie im neuen Fenster den folgenden VBA-Code in ein Modul oder Projekt ein.

Sub FindReplaceInMultipleEmails()
    Dim strFind, strReplace As String
    Dim objInspectors As Outlook.Inspectors
    Dim objInspector As Outlook.Inspector
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
 
    'Enter the specific text
    strFind = InputBox("Enter the text for find: (Case Sensitive)")
    strReplace = InputBox("Enter the text for replacement: (Case Sensitive)")
 
    If Trim(strFind) <> "" Then
       Set objInspectors = Outlook.Application.Inspectors
 
       For Each objInspector In objInspectors
           If objInspector.CurrentItem.Class = olMail Then
              If objInspector.EditorType = olEditorWord Then
                 Set objMail = objInspector.CurrentItem
                 Set objMailDocument = objMail.GetInspector.WordEditor
 
                 'Find & replace specific text
                 With objMailDocument.Content.Find
                      .ClearFormatting
                      .Text = strFind
                      .Replacement.ClearFormatting
                      .Replacement.Text = strReplace
                      .Forward = True
                      .Wrap = wdFindContinue
                      .Format = False
                      .MatchCase = True
                      .MatchWholeWord = False
                      .Execute Replace:=wdReplaceAll
                End With
                objMail.Save
             End If
         End If
      Next
 
      MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

4. Danach fügen Sie dieses Makro der Symbolleiste für den Schnellzugriff gemäß „So führen Sie VBA-Code in Outlook aus".
5. Anschließend können Sie dieses Makro jetzt ausprobieren.

• Öffnen Sie die Quell-E-Mails.
• Klicken Sie dann in der Symbolleiste für den Schnellzugriff auf die Makro-Schaltfläche.
• Als nächstes müssen Sie die spezifischen Texte eingeben, die gesucht und ersetzt werden sollen.
• Wenn Sie die Aufforderung „Abgeschlossen“ erhalten, können Sie die Quell-E-Mails überprüfen.

Wiederherstellen von Outlook nach unerwarteten Abstürzen

Outlook kann ab und zu abstürzen, wenn Sie Ihr Outlook nicht richtig handhaben. Darüber hinaus neigt Ihre Outlook-Datei bei einem schweren Outlook-Absturz dazu, beschädigt zu werden. Zu diesem Zeitpunkt müssen Sie die Outlook-Datenwiederherstellung versuchen. Ganz einfach wird es natürlich, wenn Sie eine aktuelle Datensicherung haben. Aber wenn nicht, müssen Sie ein überzeugendes und glaubwürdiges externes Tool anwenden, wie z DataNumen Outlook Repair. Es kann PST beheben Datei, ohne ins Schwitzen zu geraten.

Einführung des Autors:

Shirley Zhang ist eine Datenrettungsexpertin in DataNumen, Inc., das weltweit führend bei Datenwiederherstellungstechnologien ist, einschließlich MDF-Reparatur und Outlook-Reparatursoftwareprodukte. Für weitere Informationen besuchen Sie www.datanumen.com €XNUMX