2 วิธีในการนับอีเมลอย่างรวดเร็วโดยผู้ส่งใน Outlook ของคุณ

หากคุณต้องการนับอีเมลตามผู้ส่งคุณสามารถอ่านบทความนี้ ที่นี่เราจะเปิดเผย 2 แนวทางสั้น ๆ ให้กับคุณ

เพื่อให้ทราบว่ามost ผู้ส่งที่ใช้งานสำหรับคุณคุณอาจต้องการนับอีเมลตามผู้ส่ง แม้ว่า Outlook จะไม่มีคุณลักษณะโดยตรงสำหรับสิ่งนี้ แต่คุณยังคงสามารถหาวิธีแก้ปัญหาบางอย่างได้เช่นวิธีที่ 1 ต่อไปนี้หากคุณคิดว่าวิธีที่ 1 น่าเบื่อเกินไปคุณสามารถเลือกใช้วิธีที่ 2 ได้ซึ่งจะมีประสิทธิภาพมากกว่าใน ที่ใช้ VBA เพื่อนับอีเมลตามผู้ส่งอย่างรวดเร็วและส่งออกจำนวนไปยัง Excel ตอนนี้อ่านรายละเอียดทั้งสองวิธี ตัวอย่างเช่นเราจะใช้อีเมลใน Inbox

วิธีที่ 1: รับการนับหลังจากจัดกลุ่มรายการตามฟิลด์ "จาก"

1. ในการเริ่มต้นให้เปิดแอปพลิเคชัน Outlook
2. จากนั้นเปิดโฟลเดอร์กล่องจดหมาย
3. จากนั้นเปลี่ยนไปที่แท็บ“ ดู”
4. จากนั้นเลือก "จาก" ในกลุ่ม "การจัดเตรียม"
5. ในครั้งเดียวรายการในกล่องจดหมายทั้งหมดจะถูกแยกออกเป็นกลุ่มต่างๆตามผู้ส่งที่แตกต่างกัน
6. ตอนนี้ในการนับรายการจากผู้ส่งที่ระบุคุณสามารถเลือกรายการทั้งหมดในกลุ่มที่เกี่ยวข้องและกดปุ่ม "Enter" ในคำเตือนป๊อปอัปคุณสามารถดูจำนวนได้

ซึ่งหมายความว่าค่อนข้างง่าย แต่จริงๆแล้วการนับรายการจะรวมถึงรายการประเภทอื่น ๆ ด้วยเช่นคำเชิญเข้าร่วมการประชุมคำของานและใบเสร็จรับเงินไม่เพียง แต่จะนับอีเมลเท่านั้น ดังนั้นหากคุณต้องการนับอีเมลเท่านั้นคุณสามารถใช้วิธีต่อไปนี้แทนได้

วิธีที่ 2: นับอีเมลตามผู้ส่งด้วย Outlook VBA

1. สำหรับเป็นtart ให้กดปุ่ม“ Alt + F11” ใน Outlook
2. จากนั้นเปิดใช้งาน“ MS Excel Object Library” ตาม“วิธีเพิ่ม Object Library การอ้างอิงใน VBA"
3. จากนั้นคัดลอกโค้ดด้านล่างลงในโมดูลที่ไม่ได้ใช้

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. หลังจากนั้นกดปุ่ม“ F5”
4. เมื่อแมโครเสร็จสิ้นไฟล์ Excel ใหม่จะปรากฏขึ้น
5. อย่างที่คุณเห็นมีจำนวนอีเมลในกล่องจดหมายจากผู้ส่งรายต่างๆ

กำจัดปัญหา Outlook ที่น่าผิดหวัง

บางทีคุณอาจเคยประสบปัญหามากมายใน Outlook ของคุณ เพื่อที่จะจัดการกับปัญหาเหล่านี้อย่างมีประสิทธิภาพคุณอาจต้องการวิธีที่หลากหลายและทรงพลัง แต่ในความเป็นจริงไม่มีวิธีการดังกล่าว สิ่งที่คุณทำได้คือระวังการดำเนินการของคุณเองใน Outlook และทำการสำรองข้อมูลเป็นประจำ แน่นอนว่าถ้าเป็นไปได้เราขอแนะนำว่าคุณควรมีเครื่องมือแก้ไขที่มีประสบการณ์ติดตัวไว้ดีกว่าเช่น DataNumen Outlook Repair. สามารถแก้ไขปัญหา PST และซ่อมแซมต่างๆ PST เสียหาย ไฟล์เหมือนสายลม

บทนำผู้เขียน:

Shirley Zhang เป็นผู้เชี่ยวชาญด้านการกู้คืนข้อมูลใน DataNumen, Inc. ซึ่งเป็นผู้นำระดับโลกด้านเทคโนโลยีการกู้คืนข้อมูล ได้แก่ กู้ Sql Server และผลิตภัณฑ์ซอฟต์แวร์ซ่อมแซมแนวโน้ม ดูข้อมูลเพิ่มเติมได้ที่ wwwdatanumenด้วย.