3 snabba sätt att ta bort tomma rader och kolumner i din ordtabell

I denna sost, kommer vi att förklara för dig 3 snabba sätt att ta bort tomma rader och kolumner i din Word-tabell.

Tabeller är väsentliga för ett dokument, särskilt för att hålla olika typer av data. Ibland kan en lång tabell överstiga en sida och sträcka sig över flera. Så när en tabell blir lång och komplicerad finns det åtgärder du kan göra för att förenkla den. Du kan till exempel ta bort onödiga tomma rader och kolumner.

Följande är 3 metoder du kan använda.

Metod 1: Ta bort tomma rader och kolumner manuellt

1. Välj först en rad eller en kolumn i tomt.
2. Högerklicka sedan för att få snabbmenyn. Välj "Radera rader" eller "Radera kolumner" på menyn.

Tyvärr kan du inte välja flera icke-på varandra följande rader eller kolumner och ta bort dem tillsammans på detta sätt. För detta krav kan du hänvisa till vår tidigare artikel: 5 snabba metoder för att radera flera rader eller kolumner i din Word-tabell

Metod 2: Batchradera alla tomma rader och kolumner i en tabell

Metod 1 har sin begränsning. Så vi kommer att erbjuda dig sättet att ta bort rader och kolumner i en tabell via VBA-koder.

1. Till att börja med sätter du markören inuti a tarfå bord.
2. För det andra, utlösa VBA-redigeraren genom att trycka på "Alt + F11".
3. I redigeraren klickar du först på “Normal” -projektet.
4. Klicka sedan på fliken "Infoga" i menyraden.
5. Välj "Modul" på rullgardinsmenyn.
6. Dubbelklicka på modulen för att öppna den och klistra in följande koder där:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Klicka slutligen på "Kör" -knappen i menyraden eller tryck på "F5".

På några sekunder kommer du att ta bort alla tomma rader och kolumner i den tabellen.

Metod 3: Gruppera bort alla tomma rader och kolumner i alla tabeller i ett dokument

1. Först och främst, upprepa stegen i metod 2 för att installera och köra ett makro.
2. Bara den här gången, ersätt det makrot med följande:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Återställ brutet dokument

Det finns mer än ett sätt att hämta lost data tillbaka nuförtiden. Till exempel är alltid din högsta prioritet att använda säkerhetskopior. Om det inte uppfyller ditt behov av att få tillbaka den senaste informationen kan du prova ett doc reparation verktyg.

Författarintroduktion:

Vera Chen är en dataåterställningsexpert i DataNumen, Inc., som är världsledande inom teknik för återställning av data, inklusive xlsx reparation och pdf reparera programvaruprodukter. För mer information besök www.datanumen.com