3 raske måter å slette tomme rader og kolonner i Word-tabellen

I denne sost, vil vi forklare deg 3 raske måter å slette tomme rader og kolonner i Word-tabellen.

Tabeller er avgjørende for et dokument, spesielt når det gjelder å inneholde ulike typer data. Noen ganger kan en lang tabell overskride en side og strekke seg over flere. Så når en tabell blir lang og komplisert, er det tiltak du kan gjøre for å forenkle den. Du kan for eksempel slette unødvendige tomme rader og kolonner.

Følgende er 3 metoder du kan bruke.

Metode 1: Slett tomme rader og kolonner manuelt

1. Først velger du en rad eller kolonne i tom tilstand.
2. Høyreklikk deretter for å få opp kontekstmenyen. På menyen velger du "Slett rader" eller "Slett kolonner" tilsvarende.

Dessverre kan du ikke velge flere ikke-følgende rader eller kolonner og slette dem sammen på denne måten. For denne etterspørselen kan du se vår forrige artikkel: 5 raske metoder for å slette flere rader eller kolonner i Word-tabellen

Metode 2: Batch-slett alle tomme rader og kolonner i en tabell

Metode 1 har sin begrensning. Så vi vil tilby deg måten å batchfjerne rader og kolonner i en tabell via VBA-koder.

1. Til å begynne med setter du markøren inne i a tarfå bord.
2. For det andre, utløs VBA-editor ved å trykke "Alt+ F11".
3. I redigeringsprogrammet klikker du først på "Normal"-prosjektet.
4. Klikk deretter på "Sett inn"-fanen på menylinjen.
5. Velg "Modul" i rullegardinmenyen.
6. Dobbeltklikk på modulen for å åpne den og lim inn følgende koder der:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Til slutt klikker du på "Kjør"-knappen på menylinjen eller trykker på "F5".

I løpet av sekunder vil du få fjernet alle tomme rader og kolonner i den tabellen.

Metode 3: Batch-slett alle tomme rader og kolonner i alle tabeller i et dokument

1. Gjenta først trinn i metode 2 for å installere og kjøre en makro.
2. Bare denne gangen erstatt den makroen med følgende:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Gjenopprett ødelagt dokument

Det er mer enn en måte å hente lost data tilbake i dag. For eksempel forblir det å ty til sikkerhetskopier alltid din høyeste prioritet. Hvis det ikke tilfredsstiller ditt behov for å få den nyeste informasjonen tilbake, kan du prøve en doc reparasjon verktøyet.

Forfatterintroduksjon:

Vera Chen er en datagjenopprettingsekspert innen DataNumen, Inc., som er verdensledende innen datagjenopprettingsteknologier, inkludert xlsx reparasjon og pdf reparere programvareprodukter. For mer informasjon besøk www.datanumen. Med