How to Auto Set the Default Location for Outlook Meetings You Organize

Maybe you always schedule your meetings in the same location, such as the specific conference room in your company. If so, you may wish to set the room as the default location for all the meetings you created in Outlook. This article will help you get it.

When you create an Outlook meeting, you’re required to enter or select a location. Otherwise, you will get a warning about empty location. If you’re used to holding the meetings you initiate in a specific location, such as the same room, maybe you wish to set the room as the default meeting location. Now, the followings we will share a method with you to realize it.

Auto Set the Default Location for Meetings You Organize

1. For a start, trigger Outlook VBA editor with accordance to “How to Run VBA Code in Your Outlook:.
2. Then, in the VBA editor, copy the following code into the “ThisOutlookSession” project.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    'If it is a meeting
    If objAppointment.MeetingStatus = olMeeting Then
       'If it is a fresh new meeting
       If objAppointment.Subject = "" Then
          'Enter the specific location
          objAppointment.Location = "Conference Room A"
       End If
    Else
       objAppointment.Location = ""
    End If
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    'If you change an appointment into a meeting
    If Name = "MeetingStatus" Then
       If objAppointment.MeetingStatus = olMeeting Then
          'Enter the specific location
          objAppointment.Location = "Conference Room A"
       Else
          objAppointment.Location = ""
       End If
    End If
End Sub

3. After that, exit the VBA editor and restart Outlook to activate this macro.
4. So far, you’ve successfully set a default location for meetings you organize.

• Every time when you create a new meeting by clicking “New Meeting” on “Home” tab, the meeting will be opened with the default location filled.
• Every time when you convert an appointment into a meeting via clicking “Invite Attendees” button, the default location will be filled in “Location” field automatically.

Salvage Corrupt Outlook Data

Among all kinds of Outlook issues, the most serious one is Outlook data corruption. Generally, in face of this issue, you have to firstly figure out the real causes. Then, you can decide the solutions as per the different reasons. For example, if the file is virus-infected, you have to kill the viruses first of all. Next, you need to fix Outlook file, either by the inbuilt repair tool or a reliable external one, such as DataNumen Outlook Repair.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including corrupt sql and outlook repair software products. For more information visit www.datanumen.com