6 Ways to Keep the Original Email Attachments when Replying in Outlook

Many users hope to configure their Outlook to keep the original email attachments when replying an email. This article will expose 5 workarounds as well as a smart way, which is using VBA to realize it automatically.

I have heard a great number of users complaining that Outlook has no a native feature to keep original attachments when replying an email. Therefore, here we will share you 6 methods, one of which is pretty useful as it is using VBA to make Outlook to auto attach the original attachments to replying email. Now read on to get them in detail.

1. Reply with Original Email Attached

Though Outlook doesn’t provide a feature for keeping original email attachments when replying an email, it permits users to keep original email attached. Hence, it is an optional workaround for you. You can head to “File” > “Options” > “Mail” > “Replies and forwards” section to change the reply settings. For more details, it is suggested for you to refer to my previous article – “5 Steps to Reply with Original Attachments in Outlook”. But, if you still hope to keep original attachments only, move on to learn the other means.

2. Manually Drag & Drop Attachments

1. To start with, double click such a source email to open it in its own window.
2. Then click “Reply” button, which will bring up the replying email.
3. Next you should shrink both the two Message windows until you could see them in the same screen.
4. After that, select all the attachments in the original email.
5. Lastly, drag and drop them to the “Attached” line in the replying email.

3. Manually Copy & Paste Attachments

1. In the first place, after opening the source email, select all the attachments.
2. Then click the “Copy” button under “Attachments” tab.
3. After that, click “Reply” button under “Message” tab to open a replying mail.
4. Ultimately, in the replying email, click into the “Attached” line and press “Ctrl + V” button to paste the previously copied attachments.

4. Forward Email & Fill in Recipient

1. First off, select such an email and then click the “Forward” button in ribbon.
2. In the newly popup Message window, the original attachments are kept. Now you need to fill in the “To” field to the sender of the original email.
3. Optionally, you can change the subject as per your needs.

5. Resend This Email & Change Recipients

1. To begin with, open the source email.
2. Then click “Actions” button in “Move” group.
3. Next choose “Resend This Message” from the drop down list.
4. Perhaps you will get an alert mentioning that you aren’t the original sender. Just ignore it and hit “Yes”.
5. In the subsequent new email, you should modify the “To” field to the sender of the original email.
6. Also, remember to change the send using email account to your own account.

6. Auto Add Original Attachments via VBA

All approaches mentioned above, to be honest, are workarounds. If you hope that Outlook can automatically keep original attachments when replying, you can use this way.

1. In the main Outlook window, press “Alt + F11” keys.
2. Then, in the “Microsoft Visual Basic for Applications” window, copy the VBA code below into the “ThisOutlookSession” project.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Later sign this macro and change your Outlook macro settings to permit the signed macros.
4. After that, restart your Outlook application to activate this VBA project.
5. From now on, every time when you click “Reply” button. The replying email will display with original attachments at once.

Resort to a Preeminent Repair Tool

Outlook has shouldered over other email clients due to its myriad features. But it is still prone to corruption. Hence, you should pay more attention to its health. In general, when encountering small issues, you can simply recur to the built-in fix utility. Nevertheless, if you suffer serious troubles, you had better recur to a much more proficient tool, such as DataNumen Outlook Repair. It can fix Outlook file in an instant.

Author Introduction:

Shirley Zhang is a data recovery expert in DataNumen, Inc., which is the world leader in data recovery technologies, including sql fix and outlook repair software products. For more information visit www.datanumen.com